#asciidoctor.mbt

• The core (parser, substitutions, converters) is pure and synchronous and runs on every MoonBit backend (native, wasm-gc, js). File access goes through a small Vfs interface.
• The io package provides file-system integration on top of moonbitlang/async, and cmd/asciidoctor is a CLI.

#Converting a string

///|
test "convert a string" {
  let html = @asciidoctor.convert("A paragraph with *strong* and _emphasis_.")
  inspect(
    html,
    content=(
      #|<div class="paragraph">
      #|<p>A paragraph with <strong>strong</strong> and <em>emphasis</em>.</p>
      #|</div>
    ),
  )
}

///|
test "options" {
  let options = @core.Options::new(backend="docbook5", attributes=[
    ("product", Str("MoonBit")),
  ])
  inspect(
    @asciidoctor.convert("Hello from {product}.", options~),
    content=(
      #|<simpara>Hello from MoonBit.</simpara>
    ),
  )
}

#Working with the document model

///|
test "load and inspect" {
  let doc = @asciidoctor.load(
    (
      #|= Document Title
      #|
      #|== First Section
      #|
      #|content
    ),
  )
  inspect(doc.doctitle().unwrap(), content="Document Title")
  let section = doc.blocks[0]
  inspect(section.context.name(), content="section")
  inspect(section.title().unwrap(), content="First Section")
  inspect(section.id.unwrap(), content="_first_section")
}

#Extensions

///|
test "inline macro extension" {
  let exts = @core.Extensions::new()
  exts.inline_macro("man", (parent, target, attrs) => {
    let label = "\{target}(\{attrs.pos_str(1).unwrap_or("")})"
    Some(
      InlineNode(
        @core.create_anchor(
          parent,
          Some(label),
          "link",
          target="\{target}.html",
        ),
      ),
    )
  })
  let html = @asciidoctor.convert(
    "See man:git[1].",
    options=@core.Options::new(extensions=exts),
  )
  inspect(
    html,
    content=(
      #|<div class="paragraph">
      #|<p>See <a href="git.html">git(1)</a>.</p>
      #|</div>
    ),
  )
}

#Files and the command line

moonx bobzhang/asciidoctor/cmd/asciidoctor@latest -b html5 -a toc doc.adoc
moon run --target native cmd/asciidoctor -- -b html5 -a toc doc.adoc

#Syntax highlighting

///|
fn main {
  @pygments.register() // bobzhang/asciidoctor/highlighter/pygments
  let options = @core.Options::new(attributes=[
    ("source-highlighter", Str("pygments")),
  ])
  println(
    @asciidoctor.convert("[source,ruby]\n----\nputs 'hi'\n----", options~),
  )
}

#Status

#Layout

#Development

moon run --target native scripts/check.mbtx               # check/test on all targets + golden parity
moon run --target native scripts/check.mbtx -- --corpus   # also compare the corpora with Ruby
moon run --target native scripts/corpus.mbtx -- -v        # corpus comparison only
moon run --target native scripts/corpus.mbtx -- -b html5 --pygments --standalone  # with Pygments
moon run --target native scripts/cli_parity.mbtx -- -v    # CLI vs Ruby: exit code, stdout, stderr, files
moon run --target native scripts/harvest.mbtx             # regenerate goldens (needs Ruby + nokogiri, python3)
moon run --target native cmd/golden -- -v -n 20           # golden replay with failure details
moon run --target native cmd/golden -- --prune-known      # drop fixed entries from known_failures.txt