#$# moonast

#What it does

#A complete derive

#1 · The declaration you annotate

// models.mbt
#demo.describe
pub struct Point {
  x : Int
  y : Int
}

#2 · The generator, written once

// src/main.mbt — give every annotated struct a `describe` method
struct Describe {}

impl @gen.Generator for Describe with fn name(_) {
  "describe"
}

impl @gen.Generator for Describe with fn generate(_, decls) {
  let out = []
  for decl in decls {
    guard decl is Struct(name~, fields~, attrs~, ..) &&
      @attr.find(attrs, "demo.describe") is Some(_) else {
      continue
    }
    let text = name + "(" + fields.map(f => f.name).join(", ") + ")"
    let source =
      #|fn $T::describe(self : $T) -> String {
      #|  ignore(self)
      #|  $text
      #|}
    out.push(
      @quote.items(source)
      .set("T", @quote.ident(name))
      .set("text", @quote.string(text))
      .render(),
    )
  }
  @quote.join(out)
}

async fn main {
  @cli.run(Describe::{}, @env.args()[1:])
}

// moon.pkg of that package
import {
  "moonbitstack/moonast/quote",
  "moonbitstack/moonast/attr",
  "moonbitstack/moonast/gen",
  "moonbitstack/moonast/cli",
  "moonbitlang/async",
  "moonbitlang/core/env",
}

#3 · The rules that keep it up to date

// moon.mod of the project that uses the generator
rule(name: "describe", command: "moonx <module>@<version> -C \"$mod_dir\" \"$input\" -o \"$output\"")

// moon.pkg of the package whose declarations it reads
dev_build(rule: "describe", input: "models.mbt", output: "describe.g.mbt")
formatter(ignore: [ "describe.g.mbt" ])

#4 · The file it writes

// Generated by describe from models.mbt. Edit those files, not this one.

///|
fn Point::describe(self : Point) -> String {
  ignore(self)
  "Point(x, y)"
}

#An annotation that takes arguments

impl @gen.Generator for Getters with fn generate(_, decls) {
  let out = []
  for decl in decls {
    guard decl is Struct(name~, fields~, attrs~, ..) else { continue }
    guard @attr.find(attrs, "demo.getters") is Some(annotation) else { continue }
    let skip = @attr.Spec::new("demo.getters")
      .many("skip", Ident)
      .bind(annotation)
      .strs("skip")
    for f in fields {
      guard !skip.contains(f.name) else { continue }
      let source =
        #|fn $T::$field(self : $T) -> $Ty {
        #|  self.$field
        #|}
      out.push(
        @quote.items(source)
        .set("T", @quote.ident(name))
        .set("field", @quote.ident(f.name))
        .set("Ty", @quote.ty(f.ty).render())
        .render(),
      )
    }
  }
  @quote.join(out)
}

#demo.getters(skip=token)
pub struct User {
  id : Int
  name : String
  token : String
}

// Generated by getters from models.mbt. Edit those files, not this one.

///|
fn User::id(self : User) -> Int {
  self.id
}

///|
fn User::name(self : User) -> String {
  self.name
}

#The three packages on their own

let source =
  #|fn $T::$field(self : $T) -> $Ty {
  #|  self.$field
  #|}
let field = @quote
  .items(source)
  .set("T", @quote.ident("User"))
  .set("field", @quote.ident("id"))
  .set("Ty", @quote.ty("Int").render())
  .render()
assert_eq(
  field.to_string(),
  "///|\nfn User::id(self : User) -> Int {\n  self.id\n}\n",
)

let users =
  #|#demo.getters(skip=token)
  #|pub struct User {
  #|  id : Int
  #|  token : String
  #|}
guard @gen.read("models.mbt", users) is [decl] else { abort("one declaration") }
guard @attr.find(decl.attrs(), "demo.getters") is Some(annotation) else {
  abort("the struct is annotated")
}
let skipped = @attr
  .Spec::new("demo.getters")
  .many("skip", Ident)
  .bind(annotation)
  .strs("skip")
assert_eq(skipped.join(", "), "token")

let shapes =
  #|pub struct Rgb(Int, Int, Int)
  #|
  #|pub enum Shape {
  #|  Empty
  #|  Circle(Double)
  #|}
let kinds = @gen.read("shapes.mbt", shapes).map(decl => {
  match decl.shape() {
    Some(Tuple(arity~)) => "\{decl.name()} takes \{arity}"
    Some(Cases(cases~)) => "\{decl.name()} has \{cases.length()} cases"
    _ => "nothing to write"
  }
})
assert_eq(kinds.join("; "), "Rgb takes 3; Shape has 2 cases")

#Interface

#moonast/gen

#moonast/quote

#moonast/attr

#moonast/cli

#Holes

#Annotation arguments

#Refusals

#Examples

#Licence