#moonrockz/jmespath

#Query JSON

///|
test {
  let input = @json.parse(
    (
      #|{"items":[{"name":"Zoe","active":true},{"name":"Ada","active":true},{"name":"Bob","active":false}]}
    ),
  )
  let result = @jmespath.search("items[?active].name | sort(@)", input)
  assert_eq(result, @json.parse("[\"Ada\",\"Zoe\"]"))
}

///|
test {
  let expression = @jmespath.parse("length(@)")
  assert_eq(expression.evaluate(@json.parse("[1,2,3]")), Json::number(3))
  assert_eq(expression.evaluate(Json::string("hello")), Json::number(5))
}

#Numbers

///|
test {
  let input = @json.parse("9007199254740993")
  assert_eq(
    @jmespath.search("@ > `9007199254740992`", input),
    Json::boolean(true),
  )
  assert_eq(
    @jmespath.search("@ == `9007199254740992.0`", input),
    Json::boolean(true),
  )
}

#Behaviour changes

• to_number of a string gives a double when the string has ., e or E, and a 64-bit integer otherwise. A string that this rule does not parse, such as " 12 " or "9223372036854775808", gives null.
• -0.0 == `0` is false, because the token -0.0 is a double and Java's Double.compare puts it before 0. The token -0 is an integer and equals 0.
• A number literal keeps its token, so `1e2` prints as 1e2, not 100. The value does not change.
• Strings order by UTF-16 code unit, not by code point.
• sum, avg, abs, ceil and floor still compute with doubles. Their results have no token, so they compare by the rule for a number without a token.

#Inspect expressions and errors

///|
test {
  let source = "items["
  try {
    @jmespath.parse(source) |> ignore
    fail("expected an incomplete expression")
  } catch {
    @jmespath.JmespathError(diagnostic) => {
      assert_eq(diagnostic.code, @jmespath.Syntax)
      assert_eq(diagnostic.line_column(source), (1, 7))
    }
    error => raise error
  }
}

#Conformance