• code names the problem: KR-SCAN-* from the scanner, KR-PARSE-* and KR-ATTR-* from the parser.
• severity: an Error makes the source invalid; a Warning or an Info does not.
• span is where the problem is.

test {
  let source = @scanner.SourceText::new("x = \"abc\n")
  guard @scanner.DefaultScanner::new().tokenize(source) is Err(errors) else {
    fail("expected a scan error")
  }
  let d = errors.diagnostics[0]
  inspect(d.code, content="KR-SCAN-004")
  debug_inspect(d.severity, content="Error")
  inspect(d.title, content="ENDLESS STRING")
  inspect(d.message, content="Unterminated string literal")
  debug_inspect((d.span.start.column, d.span.end.column), content="(5, 9)")
}

• offset counts UTF-16 code units from the start of the text, from 0.
• line counts lines from 1. LF and CRLF end a line.
• column counts code points from the start of the line, from 1. A surrogate pair is one column, a lone surrogate one, a lone \r one.

test {
  let source = @scanner.SourceText::new("x = \"😀😀\" ++ y\n")
  guard @scanner.DefaultScanner::new().tokenize(source) is Ok(stream) else {
    fail("scan failed")
  }
  // The string literal: 6 UTF-16 units (two surrogate pairs and two
  // quotes), but 4 columns.
  let string = stream.tokens[2].span
  debug_inspect((string.start.offset, string.end.offset), content="(4, 10)")
  debug_inspect((string.start.column, string.end.column), content="(5, 9)")
  // The `++` after it.
  let plus = stream.tokens[3].span.start
  debug_inspect((plus.offset, plus.line, plus.column), content="(11, 1, 10)")
}

• lexeme is the exact source text of the token, and span is where it is.
• trivia_before is all the trivia between the previous token and this one.
• trivia_after is empty, except on the last token: there it holds the trivia up to the end of the text.

test {
  fn trivia_text(t : @scanner.Trivia) -> String {
    match t {
      Whitespace(text, _) | Newline(text, _) => text
      Comment(comment) => comment.text
    }
  }

  let text = "module Main exposing (..)\n\n-- The answer.\nanswer = 42 {- end -}\n"
  guard @scanner.DefaultScanner::new().tokenize(@scanner.SourceText::new(text))
    is Ok(stream) else {
    fail("scan failed")
  }
  let out = StringBuilder()
  for t in stream.trivia {
    out.write_string(trivia_text(t))
  }
  for token in stream.tokens {
    for t in token.trivia_before {
      out.write_string(trivia_text(t))
    }
    out.write_string(token.lexeme)
    for t in token.trivia_after {
      out.write_string(trivia_text(t))
    }
  }
  inspect(out.to_string() == text, content="true")
  // The line comment is trivia before `answer`.
  let answer = stream.tokens[6]
  inspect(answer.lexeme, content="answer")
  debug_inspect(
    answer.trivia_before.map(trivia_text),
    content=(
      #|["\n", "\n", "-- The answer.", "\n"]
    ),
  )
}